使用对象
在 Visual Basic中创建应用程序之际，也就是和对象打交道之时了。可以使用 Visual Basic 提供的对象, 比如控件、窗体和数据访问对象。也可以在一个 Visual Basic 应用程序内部控制另一个应用程序对象。甚至还可建立自己的对象，定义它们的属性和方法。
对象是什么
对象是代码和数据的组合，可以作为一个单位来处理。对象可以是应用程序的一部分，比如可以是控件或窗体。整个应用程序也是一个对象。下表列出了在 Visual Basic 中可能用到的几种类型的对象：
对象从何而来Visual Basic 中的每个对象都是用类定义的。用饼干模子和饼干之间的关系作比喻，就会明白对象和它的类之间的关系。饼干模子是类。它确定了每块饼干的特征，比如大小和形状。用类创建对象。对象就是饼干。
下面再用两个例子进一步说明 Visual Basic 中类与对象之间的关系。
1.在 Visual Basic 的“工具箱”上，控件代表类。直到在窗体上画出这些被称作控件的对象为止，它们实际上并不存在。在创建控件之时也就是在复制控件类，或建立控件类的实例。这个类实例就是应用程序中引用的对象。
2.在设计时操作的窗体是类。在运行时，Visual Basic 建立窗体的类实例。“属性”窗口显示Visual Basic应用程序中的对象的类和Name属性，如图5.8所示。
把对象看作是类的原原本本的复制品，从而建立所有对象。一旦它们以单个对象的形式存在，属性就可改变。例如，如果在窗体上画了三个命令按钮，则每个命令按钮对象都是命令按钮类的实例。 每个对象都具有一组由类定义的公共的特征和功能（属性、方法和事件）。但是，每个对象都有自己的名字，都能分别设置成有效或无效，都能放在窗体的不同位置，等等。
为简单起见，本章之外的大部分内容将不过多引用对象的类。例如，只要记住术语“ListBox 控件”意味着“列表框类的一个实例”。
用对象能做什么
对象可提供现成代码，省却书写麻烦。例如，可以自己创建打开文件和保存文件的对话框，但实际上大可不必。取而代之的是利用 Visual Basic 提供的 CommonDialog 控件（一个对象）。虽然用户也能撰写日程管理和资源管理的程序，但也大可不必。在此亦可使用 Microsoft Project 提供的Calendar、Resources 和 Task 对象。
Visual Basic 可以组合来自其它来源的对象
Visual Basic 提供了把来自不同资源的对象组合起来的工具。现在可把Visual Basic 的各种强有力的特性以及支持自动化（先前以 OLE 自动化闻名）的应用程序结合起来，建立定制的解决方法。自动化是部件对象模式(COM) 的一个特性，它是应用程序使用的工业标准，用来陈列对象以开发工具和其它应用程序。
可把 Visual Basic 内部的控件结合在一起，也可使用其它应用程序提供的对象。考虑把下列对象放入 Visual Basic 窗体： 1.Microsoft Excel Chart 对象
2.Microsoft Excel Worksheet 对象
3.Microsoft Word Document 对象
可用这些对象建立如图 5.9 所示的支票簿应用程序。由于不必书写代码，重建已由 Microsoft Excel 和 Word 等对象提供的功能，因而节省很多时间。
使用对象初步
Visual Basic 对象支持属性、方法和事件。在 Visual Basic 中，称对象的数据（设置和属性）为属性，称各种可在对象上操作的过程为方法。事件是可被对象识别的动作，例如单击鼠标和按下键盘键，还可编写代码来响应事件。
改变对象的属性就可改变对象的特性。用收音机打比方，收音机的一个属性是音量。用 Visual Basic 的行话来说，就是收音机有个“Volume”属性，改变其值就可调节音量大小。假定收音机的音量值可设置在 0 到 10 之间。 如果能够通过 Visual Basic 控制收音机，则可在一个过程中写代码，把“Volume”属性值从 3 提高到 5，使声音更响一些：
Radio.Volume = 5
除了属性以外，对象还有方法。方法和属性都是对象的一部分。一般说来，方法就是要执行的动作，而属性就是要设置或检索的特性。以拨号打电话为例。可以说电话有一个“拨号”方法，拨一个 7 位电话号码的语法就是：
Phone.Dial 5551111
对象还有事件。当对象的某方面有变动时就触发了事件。例如，收音机可能有“VolumeChange”事件。电话可能有“Ring”事件，等等。
用属性控制对象
个别属性随着可以设置和取得它们的值的时间不同而不同。有的属性可在设计时设置。可在“属性”窗口设置这些属性的值而无需编写任何代码。而有的属性在设计时是不可用的；因此，这些属性只有通过代码在运行时设置。
在运行时可以设置并可获得值的属性叫做读写属性。在运行时只能读取的属性叫做只读属性。
设置属性值
在想改变对象的外观或特性时设置属性的值。例如，通过改变 TextBox 控件的 Text 属性，就可以改变文本框的内容。
用下列语法设置属性值：
object.property = expression
下面是设置属性的语句：
Text1.Top = 200 ' 设置 Top 属性为 200 缇（twips）。
Text1.Visible = True ' 显示文本框。
Text1.Text = "hello" ' 在文本框中显示 "hello"。
读取属性值
想要在代码执行附加动作（例如给另一个对象赋值）之前得知对象的状态，这时就要读取属性值。例如，在运行代码之前能够返回 TextBox 控件的 Text属性值，以确定文本框的内容，这里，代码可能改变值。
在大多数情况下可以用以下语法获得属性值：
variable = object.property
属性值可以作为较复杂的表达式的一部分，而不必将属性赋予变量。下面的代码计算控件数组中的一个新成员的 Top 属性，它等于前一个成员的Top 属性加上 400。
Private Sub cmdAdd_Click ()
' [语句]
optButton (n).Top = optButton (n-1).Top + 400
' [语句]
End Sub
提示 如果不只一次使用一个属性值，而且将这个值存储到一个变量中，则代码执行起来会更快。
用方法来执行动作
方法能够影响属性值。例如在用收音机打比方的例子中，SetVolume 方法改变了 Volume 属性。与此类似，在 Visual Basic 中列表框具有 List 属性，而 Clear 和 AddItem 方法可以改变这一属性。
在代码中使用方法
在代码中使用方法时如何书写语句，这取决于该方法要求多少参数，以及是否返回一个值。如果方法不要求参数，则用以下语法编写代码：
object.method
下例中，用 Refresh 方法重画图片框：
Picture1.Refresh ' 强迫重画控件。
有些方法，如上面的 Refresh ，既无参数又不返回值。
如果方法要用多个参数，就用逗号将它们分开。例如， Circle 方法就要用代表窗体上圆的位置、半径和颜色的参数：
' 画一个半径为 1200 缇的蓝色圆。
Form1.Circle (1600, 1800), 1200, vbBlue
如果要保存方法的返回值，就必须把参数用括号括起来。例如， GetData 方法从剪贴板返回一张图片：
Picture = Clipboard.GetData (vbCFBitmap)
如果没有返回值，则参数不会出现在括号中。例如，AddItem 方法没有返回值。
List1.AddItem "yourname" ' 在列表框中添加 "yourname"。
详细信息 关于 Visual Basic 对所有方法提供的语法和参数，请参阅《VisualBasic 6.0语言参考手册》。
对象之间的关系
在同一窗体上放置两个命令按钮时，它们是两个具有不同 Name 属性设置值（Command1 和 Command2）的分开的对象，但都分享同一个类——命令按钮。
它们也共享这样一个特征，即它们在同一窗体上。在本章前面已看到，窗体上的控件也包含在窗体中。这就把控件放在一个层次上。要引用控件就必须先引用窗体，就如同打电话拨号一样，首先要拨国家/地区号码或区域号码，然后再拨具体的电话号码。
这两个命令按钮也共享这样一个特征，即它们都是控件。所有控件都具有公共特性，使它们不同于窗体以及 Visual Basic 环境中的其它对象。以下章节中将说明 Visual Basic 如何用集合使相关的对象分组。
对象的层次
对象层次提供了一种组织结构，它决定了对象间的相互关系以及访问它们的方法。在大多数情况下不必考虑 Visual Basic 对象的层次。但是：
1.在操作其它应用程序的对象时，应当熟悉那个应用程序的对象层次。关于定位对象层次的信息，请参阅第十章“用部件编程”。
2.在使用数据访问对象时，应当熟悉数据访问对象层次。在 Visual Basic 中，一个对象包含其它对象的一般情况时有发生。下面我们要详细讨论。
使用对象集合
集合对象有自己的属性和方法。对象集合中的对象作为集合的成员被引用。集合中的每个成员从 0 开始顺次编号；这就是成员的索引号。例如，控件集合包含已给定窗体上的所有控件 ，如图 5.10 所示。如果对集合中的所有对象都必须执行相同操作，则可用集合简化代码。
例如，下列代码遍历控件集合，并在列表框中列出每个成员的名字。
Dim MyControl as Control
For Each MyControl In Form1.Controls
'把每个控件的名字送到列表框。
List1.AddItem MyControl.Name
Next MyControl
应用集合成员的属性与方法
有两种通用方法可用来对集合对象成员寻址：
1.指定成员的名称。以下两个表达式等价：
Controls ("List1")
Controls!List1
2.利用成员的索引号：
Controls (3)
一旦能够从整体上对全体成员寻址，而且还能够个别地对单个成员寻址，就可用下面随便一种方式应用属性和方法：
'将 ListBox 控件的 Top 属性设置为 200。Controls!List1.Top = 200
－或者－
Dim MyControl as Control
For Each MyControl In Form1.Controls ()
'将每一个成员的 Top 属性设置为 200。
MyControl.Top = 200
Next MyControl
包含其它对象的对象
在 Visual Basic 中，一些对象包含其它对象。例如，窗体通常包含一个或数个控件。把一个对象当作其它对象的容器，这样做的好处在于，在代码中引用容器即可明了要使用哪个对象。例如，图 5.11 说明在一个应用程序中可有两个不同的窗体，一个用来输入应付帐交易，另一个用来输入应收帐交易。
两个窗口可以有名为 IstAcctNo 的列表框。通过引用包含列表框的窗体就可准确指定要使用的列表框： frmReceivable.lstAcctNo.AddItem 1201
－或者－
frmPayable.lstAcctNo.AddItem 1201
Visual Basic 中的公共集合
在 Visual Basic 中一个对象包含其它对象的一般情况时有发生。下表简要叙述 Visual Basic 中最常用的集合。
在 Visual Basic 中也可实现对象控制。
详细信息 关于对象容器的详细信息，请参阅第八章“再论编程”中的“使用集合替代数组”。关于打印机集合的信息，参阅第十二章“使用文本和图形”。关于窗体集合和控件集合的详细信息，请参阅《Visual Basic 6.0语言参考手册》。
容器属性在窗体内，可用 Container 属性改变对象的容器。以下控件可包含其它控件：
1.Frame 控件
2.PictureBox 控件
3.ToolBar 控件（仅对专业版和企业版而言）
如何在窗体上将命令按钮从一个容器移动到另一个容器，该例对此作了演示。打开新工程，并在窗体上画出 Frame 控件、PictureBox 控件和CommandButton 控件。
下列代码在窗体单击事件中，这些代码使计数器变量增加，并通过 SelectCase 循环使命令按钮在容器之间移动。
Private Sub Form_Click ()
Static intX as Integer
Select Case intX
Case 0
Set Command1.Container = Picture1
Command1.Top= 0
Command1.Left= 0
Case 1
Set Command1.Container = Frame1
Command1.Top= 0
Command1.Left= 0
Case 2
Set Command1.Container = Form1
Command1.Top= 0
Command1.Left= 0
End Selectint
X = intX + 1
End Sub
详细信息 请参阅《Visual Basic 6.0语言参考手册》中的“Container 属性”。
对象之间的通讯
除了在 Visual Basic 中使用和创建对象外，还可与其它应用程序通讯并在自己的应用程序中操作其它应用程序的对象。在应用程序之间共享数据的能力是 Microsoft Windows 操作系统的关键性能之一。有了 Visual Basic，与其它应用程序进行通讯变得极为灵活。
详细信息 关于使用其它应用程序的对象及其通讯的详细信息，请参阅第十章“用部件编程”。
创建对象
创建对象的最简单方法是在“工具箱”中双击控件。但是，对 Visual Basic 中的所有可用对象以及来自其它应用程序的所有可用对象，要想充分体现它们的优势，可在运行时用 Visual Basic 的可编程性能创立对象。
1.用对象变量创建对象引用
2.用类模块“从零开始”创建自己的对象
3.用集合对象创建自己的集合
详细信息 在其它章节将会介绍如何访问对象。例如，在第十章“用部件编程”中将讨论 CreateObject 和 GetObject 函数。
使用对象变量
除了存储值以外，变量可引用对象。如同给变量赋值一样，基于下列相同理由，可把对象赋给变量：
1.变量名往往比变量所含的值（或者，在此情况下，所含值就是它们引用的对象）短而好记。
2.在运行代码时，为了引用其它对象，应改变变量。
3.引用包含对象的变量比反复引用对象本身有更高的效率。
使用对象变量与使用常规变量一样，只不过多了把对象赋予变量这一步：
4.首先声明变量：
Dim variable As class
5.然后把对象赋予变量：
Set variable = object
声明对象变量
声明对象变量的方法和声明其它变量一样，要用 Dim、ReDim、Static、Private和 Public。仅有的不同在于可选的 New 关键字和 Class 参数，本章后面将会对 New 关键字和 Class 参数都作介绍。语法是：
{Dim | ReDim | Static | Private | Public} variable As [New] class
例如，可以声明一个对象变量，它引用应用程序中的被称做 frmMain 的窗体：
Dim FormVar As New frmMain '声明一个类型为 frmMain
'的对象变量。
也可以声明一个对象变量，它引用应用程序中的任何窗体：
Dim anyForm As Form '一般窗体变量。
类似地，可以声明一个对象变量，它能够引用应用程序中的任何文本框：
Dim anyText As TextBox '可以引用任何文本框
'（但只能是一个文本框）。
还可以声明一个对象变量，它能够引用任何类型的控件：
Dim anyControl As Control '一般控件变量。
注意，可以声明一个引用应用程序中的指定窗体的窗体变量，但不能声引用特定控件的控件变量。可以声明能够引用控件的特定类型（如 TextBox或列表框）的控件变量，但不是引用那种类型的一个特定控件（如 txtEntry 或List1）。但是，可把特定的控件赋予那种类型的变量。例如，对于具有列表框 lstSample 的窗体可以这样编码：
Dim objDemo As ListBox
Set objDemo = lstSample
赋值对象变量
用 Set 语句将对象赋予对象变量：
Set variable = object
无论何时，只要希望对象变量引用对象，就可使用 Set 语句。
有时可用对象变量，尤其可用控件变量直接缩短要键入的代码。例如，原来的代码是这样的：
If frmAccountDisplay!txtAccountBalance.Text < 0 Then
frmAccountDisplay!txtAccountBalance.BackColor = 0
frmAccountDisplay!txtAccountBalance.ForeColor = 255
End If
如果使用控件变量，程序就可显著缩短：
Dim Bal As TextBox
Set Bal = frmAccountDisplay!txtAccountBalance
If Bal.Text < 0 Then
Bal.BackColor = 0
Bal.ForeColor = 255
End If
特定对象类型与一般对象类型
特定的对象变量必须引用特定类型的对象或类。特定的窗体变量只能引用应用程序中的一个窗体（尽管可在该窗体的诸多实例中引用其中之一）。与此相似，特定的控件变量只能引用应用程序中的特定类型的控件，比如TextBox 或者列表框。请看一例，打开新的工程，在窗体中放置一文本框。将下列代码添加到窗体中：
Private Sub Form_Click ()
Dim anyText As TextBox
Set anyText = Text1
anyText.Text = "Hello"
End Sub
运行应用程序并单击窗体。文本框的 Text 属性将变成 "Hello"。
一般对象变量可在多种特定对象类型中引用其中一种。例如，一般窗体变量可引用应用程序中的任何窗体；一般控件变量可引用应用程序中任何窗体上的任何控件。请看一例，打开新的工程并在窗体中按任意顺序放置若干 Frame、Label 和 CommandButton 控件。将下列代码添加到窗体中：
Private Sub Form_Click ()
Dim anyControl As Control
Set anyControl = Form1.Controls (3)
anyControl.Caption = "Hello"
End Sub
运行程序并单击窗体。刚才放入窗体中的第三个控件的标题将变成"Hello"。
Visual Basic 中有四种一般对象：
在不知道变量运行时是否引用特定类型的对象时，一般对象变量是很有用的。例如，如果要书写代码，并使之在应用程序的任何窗体中都可操作，则必须使用一般窗体变量。
注意 由于应用程序中只能有一个 MDI 窗体，因此不必使用一般的MDIForm 类型。无论何时，一旦需要声明引用 MDI 窗体的窗体变量，就可用特定的 MDIForm 类型（或者是 MDIForm1，或者是对 MDI窗体的 Name 属性指定的任何名称），而不用一般的 MDIForm 类型。实际上，由于在运行应用程序前，Visual Basic 就能够决定引用特定窗体类型的属性和方法，因此总应使用特定的 MDIForm 类型。
只是出于完整性的考虑才提供一般的 MDIForm 类型；在 Visual Basic 的今后版本中，单个应用程序中可以拥有多个 MDI 窗体，这将是非常有用的。
作为对象的窗体
窗体最常用到的是构造应用程序界面，但也常常是应用程序中其它模块调用的对象。窗体与类模块关系密切。两者之间的主要区别在于，窗体是可视对象，而类模块却没有可视界面。
添加自定义方法和属性
可对窗体添加自定义方法和属性，并可从应用程序中的其它模块访问它们。为了创建窗体的新方法，请添加用 Public 声明的过程。
'自定义 Form1 的方法。
Public Sub LateJobsCount ()
.
. ' <statements>
.
End Sub
可用下面这个语句从其它模块调用 LateJobsCount 过程：
Form1.LateJobsCount
创建窗体的新属性就像在窗体模块中声明一个公用变量那样简单：
Public IDNumber As Integer
可用下面两个语句从其它模块设置和返回 Form1 的 IDNumber 值：
Form1.IDNumber = 3
Text1.Text = Form1.IDNumber
也可用 Property 过程向窗体添加自定义属性。
详细信息 第九章“用对象编程”提供了 Property 过程的详细材料。
注意 不必加载窗体就可调用窗体的变量或自定义方法，还可设置窗体的自定义属性。于是，不必将窗体加载到内存就可运行有关窗体的代码。同样，引用控件而不引用其属性或方法时也不会加载窗体。
使用 New 关键字
用 New 关键字创建新对象，这个对象被视为它的类所定义的对象。可用New 创建集合、窗体的实例以及类模块中定义的类。
在窗体上使用 New 关键字
在设计时创建的窗体是类。可用 New 关键字创建这个类的新实例。为了看到这一工作过程，请在窗体上画出一个命令按钮和其它几个控件。在“属性”窗口中将窗体的 Name 属性设置成 Sample。在命令按钮的 Click 事件过程中添加下列代码：
Dim x As New Sample
x.Show
运行应用程序，并单击命令按钮数次。把最前面的窗体移到一边。因为窗体是具有可视界面的类，所以可看到附加副本。每个窗体在相同位置上都有相同控件，而且这些位置也正是窗体在设计时的位置。
注意 要使窗体变量和已加载窗体的实例一直存在，请用 Static 或 Public变量，而不要用局部变量。
也可将 New 关键字与 Set 语句并用。请试用命令按钮的 Click 事件过程中的代码：
Dim f As Form1
Set f = New Form1
f.Caption = "hello"
f.Show
将 New 关键字和 Set 语句并用会加快运行速度，因此，这种方法值得推荐。
对其它对象使用 New 关键字
可用 New 关键字从类模块中定义的类创建集合和对象。试用下例说明这一工作过程。
此例说明了 New 关键字是如何创建类的实例的。打开新工程，在 Form1 上画出一个 CommandButton 控件。从“工程”菜单中选择“添加类模块”命令，从而在工程中添加一个类模块。设置类模块的 Name 属性为ShowMe 。
Form1 中的下列代码创建了类 ShowMe 的新实例，还调用了包含在类模块中的过程。
Public clsNew As ShowMe
Private Sub Command1_Click ()
Set clsNew = New ShowMe
clsNew.ShowFrm
End Sub
类模块中的 ShowFrm 过程创建类 Form1 的新实例，显示窗体，然后使其最小化。
Sub ShowFrm ()
Dim frmNew As Form1
Set frmNew = New Form1
frmNew.Show
frmNew.WindowState = 1
End Sub
为了应用这个例子，请运行应用程序并单击命令按钮数次。在创建 ShowMe类的每一个新实例时将看到最小化的窗体图标出现在桌面上。
详细信息 关于利用 New 创建对象的信息，请参阅第十章“用部件编程”。
New 关键字的限制
下表说明不能用 New 关键字做什么。
释放对对象的引用
每个对象都使用内存和系统资源。当不再使用对象时及时释放这些资源，这是良好的编程习惯。
用 Unload 从内存中卸载窗体或控件。
用 Nothing 释放对象变量占用的资源。用 Set 语句将 Nothing 赋予对象变量。
详细信息 请参阅《Visual Basic 6.0语言参考手册》中的“Unload 事件”和“Nothing”部分。
给过程传递对象
可在 Visual Basic 中将对象传递给过程。在下面的代码例子中假定窗体中有一 CommandButton 控件：
Private Sub Command1_Click ()
'调用 Demo 子过程，并将窗体传递给它。
Demo Form1
End Sub
Private Sub Demo (x As Form1)
'在屏幕中使窗体居中。
x.Left = (Screen.Width - x.Width) / 2
End Sub
可以通过引用把对象传递给参数，然后在过程内将参数设置成新对象。为了看到这一工作过程，打开工程并插入第二个窗体。在每个窗体中安放一个图片框。需要改变的属性设置值如下表所示：
Form1_Click 事件过程调用 Form2 中的 GetPicture 过程，并把一个空的图片框传递给它。
Private Sub Form_Click ()
Form2.GetPicture Picture1
End Sub
Form2 中的 GetPicture 过程把 Form2 上的图片框的 Picture 属性赋予Form1 上的空图片框。
Private objX As PictureBox
Public Sub GetPicture (x As PictureBox)
'将传递进来的图片框赋予对象变量。
Set objX = x
'将 Picture 属性值赋予 Form1 的图片框。
objX.Picture = picture2.Picture
End Sub
为了应用这个例子，请运行程序并单击 Form1。在 Form1 的图片框中将看到出现了 Form2 中的图标。
详细信息 上述主题意在概述对象。更详细内容，请参阅第九章“用对象编程”和第十章“用部件编程”。
|
