Excel技巧应用篇：计算 Excel 中包含特定文本的单元格数量

假设您有一个文本字符串列表，并且可能想要查找包含某些文本作为其内容一部分的单元格的数量。在这种情况下，您可以在应用 COUNTIF 函数时使用表示条件中的任何文本或字符的通配符 (*)。这篇文章，我将介绍如何在Excel中使用公式来处理这项工作。

计算包含特定文本但不区分大小写的单元格数量

要计算匹配部分文本字符串的单元格数量，Excel 中的 COUNIF 函数可以帮助您，请执行以下操作：

带有硬编码文本的通用公式：

= COUNTIF ( range, "*text*" )

• range: 单元格范围包含要计数的文本字符串；

• *: 查找任意数量字符的通配符；

• text: 要查找的特定文本或字符。

如下图所示，我想计算包含 A2:A11 范围内特定文本“Tokyo”的单元格数量。

请输入或复制以下公式到空白单元格中，然后按 输入返回结果的关键，请参见屏幕截图：

=COUNTIF(A2:A11,"*Tokyo*")

---

带单元格引用的通用公式：

= COUNTIF ( range, "*" & cell & "*" )

• range: 单元格范围包含要计数的文本字符串；

• *: 查找任意数量字符的通配符；

• cell：单元格包含要查找的特定文本或字符。

要动态生成公式，请将硬编码字符串替换为单元格引用。例如，将条件文本放入单元格 C2:C4，要计算包含这些文本的一部分的单元格，请按此操作。

1. 将以下公式输入或复制到空白单元格中以输出结果：

=COUNTIF($A$2:$A$11, "*"&C2&"*")

2. 然后将填充手柄向下拖动到要应用此公式的单元格，您将获得如下屏幕截图所示的结果：

小贴士：如果要计算包含多个文本条件的单元格数量，例如，计算 A1: A2 范围内包含“Tokyo”和“Class11”项的单元格，如下图所示：

要计算具有多个子字符串的单元格，请根据需要应用以下公式之一：

=COUNTIFS(A2:A11,"*Tokyo*", A2:A11,"*Class1*")
=COUNTIFS(A2:A11,"*"&C2&"*", A2:A11,"*"&C3&"*")

---

计算包含区分大小写的特定文本的单元格数量

要计算包含与指定单元格中的大小写文本完全匹配的区分大小写的特定文本的单元格数量，您应该结合 SUMPRODUCT、ISNUMBER 和 FIND 函数来完成它，通用语法是：

=SUMPRODUCT(--(ISNUMBER(FIND("text", range))))

• text：文本或单元格包含您要查找的文本；

• range：单元格范围包含要计数的文本字符串。

请输入或复制以下公式到空白单元格中，然后按 输入获得结果的关键：

=SUMPRODUCT(--(ISNUMBER(FIND(C2, A2:A11))))

---

公式说明：

• 查找(C2, A2:A11)：FIND 函数区分大小写，它在范围的每个单元格中搜索特定文本。如果文本存在，则返回第一个字符的位置，否则返回#VALUE！返回错误。所以，你会得到这样的数组：{7;#VALUE!;#VALUE!;#VALUE!;1;6;#VALUE!;#VALUE!;#VALUE!;#VALUE!}。

• ISNUMBER(查找(C2, A2:A11))：此 ISNUMBER 函数会将数字转换为 TRUE，并将错误值转换为 FALSE，如下所示：{TRUE;FALSE;FALSE;FALSE;TRUE;TRUE;FALSE;FALSE;FALSE;FALSE}。

• --(ISNUMBER(查找(C2, A2:A11)))：双负号 (--) 用于将 TRUE 和 FALSE 值转换为 1 和 0 数字，如下所示：{1;0;0;0;1;1;0;0;0;0}。

• SUMPRODUCT(--(ISNUMBER(FIND(C2, A2:A11))))=SUMPRODUCT({1;0;0;0;1;1;0;0;0;0}): 最后，这个 SUMPRODUCT 函数将数组中的所有数字相加得到最终结果：3。

小伙伴们，你们学会了吗？